OberonCore

MODULE RandomNet; (* From Microsoft .NET Framework 2.0 *)

  VAR
    inext, inextp: INTEGER;
    SeedArray: ARRAY 56 OF INTEGER;

  PROCEDURE Random* (): REAL;
  VAR index, inextp1, num: INTEGER;
  BEGIN
    index := inext;
    inextp1 := inextp;
    INC(index);
    IF index >= 56 THEN index := 1 END;
    INC(inextp1);
    IF inextp1 >= 56 THEN inextp1 := 1 END;
    num := SeedArray[index] - SeedArray[inextp1];
    IF num < 0 THEN INC(num, 2147483647) END;
    SeedArray[index] := num;
    inext := index;
    inextp := inextp1;
    RETURN num * 4.6566128752457969E-10;
  END Random;

  PROCEDURE InitSeed* (seed: INTEGER);
  VAR num2, num3, i, j, k, index: INTEGER;
  BEGIN
    num2 := 161803398 - ABS(seed);
    SeedArray[55] := num2;
    num3 := 1;
    FOR i := 1 TO 54 DO
      index := (21 * i) MOD 55;
      SeedArray[index] := num3;
      num3 := num2 - num3;
      IF num3 < 0 THEN INC(num3, 2147483647) END;
      num2 := SeedArray[index]
    END;
    FOR j := 1 TO 4 DO
      FOR k := 1 TO 55 DO
        DEC(SeedArray[k], SeedArray[1 + ((k + 30) MOD 55)]);
        IF SeedArray[k] < 0 THEN INC(SeedArray[k], 2147483647) END
      END
    END;
    inext := 0;
    inextp := 21;
  END InitSeed;

BEGIN
  InitSeed(314159)
END RandomNet.

MODULE RandomTest;

  IMPORT Log, R := RandomNet, WinApi;

  CONST n = 3000;

  VAR M: ARRAY n, n OF REAL;

  PROCEDURE Sum (): REAL;
  VAR i, j: INTEGER; s: REAL;
  BEGIN
    FOR i := 0 TO n-1 DO
      FOR j := 0 TO n-1 DO
        M[i,j] := R.Random();
      END;
    END;
    s := 0;
    FOR i := 0 TO n-1 DO
      FOR j := 0 TO n-1 DO
        s := s + M[i,j];
      END;
    END;
    RETURN s;
  END Sum;

  PROCEDURE Do*;
  VAR tc1, tc2: INTEGER; r: REAL;
  BEGIN
    tc1 := WinApi.GetTickCount();
    r := Sum();
    tc2 := WinApi.GetTickCount();
    Log.Real(r); Log.Ln;
    Log.Int(tc2-tc1); Log.Ln;
  END Do;

END RandomTest.